'From Squeakland 3.8.5976 of 25 August 2004 [latest update: #388] on 20 February 2005 at 8:17:49 pm'!
"Change Set:		MPEGDisplayTranslation
Date:			20 February 2005
Author:			Yoshiki Ohshima

A few translations for MPEGDisplayMorph."!


!MPEGDisplayMorph methodsFor: 'menu' stamp: 'yo 2/20/2005 20:10'!
createJPEGfromFolderOfFrames
	"Create a new JPEG movie file from an folder of individual frames. Prompt the user for the folder and file names and the quality setting, then do the conversion."

	| result folderName jpegFileName q frameRate |
	result := StandardFileMenu oldFile.
	result ifNil: [^self].
	folderName := result directory pathName.
	jpegFileName := FillInTheBlank request: 'New movie name?' translated.
	jpegFileName isEmpty ifTrue: [^self].
	(jpegFileName asLowercase endsWith: '.jmv') 
		ifFalse: [jpegFileName := jpegFileName , '.jmv'].
	result := FillInTheBlank request: 'Quality level (1 to 100)?' translated.
	q := result ifNil: [50]
				ifNotNil: [(result asNumber rounded max: 1) min: 100].
	result := FillInTheBlank request: 'Frame rate?' translated.
	frameRate := result ifNil: [10]
				ifNotNil: [(result asNumber rounded max: 1) min: 100].
	JPEGMovieFile 
		convertFromFolderOfFramesNamed: folderName
		toJPEGMovieNamed: jpegFileName
		frameRate: frameRate
		quality: q! !

!MPEGDisplayMorph methodsFor: 'menu' stamp: 'yo 2/20/2005 20:04'!
createJPEGfromMPEG
	"Create a new JPEG movie file from an MPEG movie. Prompt the user for the file names and the quality setting, then do the conversion."

	| result mpegFileName jpegFileName q |
	result := StandardFileMenu oldFile.
	result ifNil: [^self].
	mpegFileName := result directory pathName , FileDirectory slash 
				, result name.
	jpegFileName := FillInTheBlank request: 'New movie name?' translated.
	jpegFileName isEmpty ifTrue: [^self].
	(jpegFileName asLowercase endsWith: '.jmv') 
		ifFalse: [jpegFileName := jpegFileName , '.jmv'].
	result := FillInTheBlank request: 'Quality level (1 to 100)?' translated.
	q := result ifNil: [50]
				ifNotNil: [(result asNumber rounded max: 1) min: 100].
	JPEGMovieFile 
		convertMPEGFileNamed: mpegFileName
		toJPEGMovieNamed: jpegFileName
		quality: q! !

!MPEGDisplayMorph methodsFor: 'menu' stamp: 'yo 2/20/2005 20:05'!
createJPEGfromSqueakMovie
	"Create a new JPEG movie file from an SqueakTime movie. Prompt the user for the file names and the quality setting, then do the conversion."

	| result squeakMovieFileName jpegFileName q |
	result := StandardFileMenu oldFile.
	result ifNil: [^self].
	squeakMovieFileName := result directory pathName , FileDirectory slash 
				, result name.
	jpegFileName := FillInTheBlank request: 'New movie name?' translated.
	jpegFileName isEmpty ifTrue: [^self].
	(jpegFileName asLowercase endsWith: '.jmv') 
		ifFalse: [jpegFileName := jpegFileName , '.jmv'].
	result := FillInTheBlank request: 'Quality level (1 to 100)?' translated.
	q := result ifNil: [50]
				ifNotNil: [(result asNumber rounded max: 1) min: 100].
	JPEGMovieFile 
		convertSqueakMovieNamed: squeakMovieFileName
		toJPEGMovieNamed: jpegFileName
		quality: q! !