'From Squeakland 3.8.5976 of 25 August 2004 [latest update: #387] on 18 January 2005 at 1:42:56 pm'!
"Change Set:		stampOnTransformedOwner.cs
Date:			18 January 2005
Author:			Takashi Yamamiya

The change set allows you to stamp a moprh
even in rotated owner.
"!


!Morph methodsFor: 'pen' stamp: 'tak 1/17/2005 10:22'!
addImageToPenTrails: aForm 
	owner
		ifNil: [^ self].
	owner addImageToPenTrails: aForm! !

!Morph methodsFor: 'pen' stamp: 'tak 1/17/2005 10:21'!
stamp
	self addImageToPenTrails: self imageForm! !


!PasteUpMorph methodsFor: 'pen' stamp: 'tak 1/18/2005 13:40'!
addImageToPenTrails: aForm 
	"The turtleTrailsForm is created on demand when the first pen is put  
	down and removed (to save space) when turtle trails are cleared."
	self createOrResizeTrailsForm.
	aForm
		displayOn: turtleTrailsForm
		at: self topLeft negated
		rule: Form paint.
	self
		invalidRect: (aForm offset extent: aForm extent)! !


!Player methodsFor: 'costume' stamp: 'tak 1/17/2005 13:32'!
stamp

	"stamp an image of ourself onto the pen trails form"

	costume stamp! !


!TransformMorph methodsFor: 'drawing' stamp: 'tak 1/17/2005 13:16'!
addImageToPenTrails: aForm 
	| canvas |
	owner
		ifNil: [^ self].
	canvas := Display defaultCanvasClass extent: self extent depth: Display depth.
	canvas
		translateBy: self topLeft negated
		during: [:tempCanvas | tempCanvas
				transformBy: transform
				clippingTo: self innerBounds
				during: [:myCanvas | myCanvas drawImage: aForm at: aForm offset]
				smoothing: smoothing].
	owner
		addImageToPenTrails: (canvas form offset: self topLeft)! !